;-------------------------------------------------------------
;+
; NAME:
;       MONTHNAMES
; PURPOSE:
;       Returns a string array of month names.
; CATEGORY:
; CALLING SEQUENCE:
;       mnam = mnthnmes()
; INPUTS:
; KEYWORD PARAMETERS:
; OUTPUTS:
;       mnam = string array of 13 items:     out
;         ['Error','January',...'December']
; COMMON BLOCKS:
; NOTES:
; MODIFICATION HISTORY:
;       R. Sterner, 18 Sep, 1989
;
; Copyright (C) 1989, Johns Hopkins University/Applied Physics Laboratory
; This software may be used, copied, or redistributed as long as it is not
; sold and this copyright notice is reproduced on each copy made.  This
; routine is provided as is without any express or implied warranties
; whatsoever.  Other limitations apply as described in the file disclaimer.txt.
;-
;-------------------------------------------------------------

	function mnthnmes, help=hlp

	if keyword_set(hlp) then begin
	  print,' Returns a string array of month names.'
	  print,' mnam = mnthnmes()'
	  print,'   mnam = string array of 13 items:     out'
	  print,"     ['Error','January',...'December']"
	  return, -1
	endif

	mn = ['Error','January','February','March','April','May',$
	      'June','July','August','September','October',$
	      'November','December']

	return, mn
	end

;-------------------------------------------------------------
;+
; NAME:
;       YMD2JD
; PURPOSE:
;       From Year, Month, and Day compute Julian Day number.
; CATEGORY:
; CALLING SEQUENCE:
;       jd = ymd2jd(y,m,d)
; INPUTS:
;       y = Year (like 1987).                    in
;       m = month (like 7 for July).             in
;       d = month day (like 23).                 in
; KEYWORD PARAMETERS:
; OUTPUTS:
;       jd = Julian Day number (like 2447000).   out
; COMMON BLOCKS:
; NOTES:
; MODIFICATION HISTORY:
;       R. Sterner,  23 June, 1985 --- converted from FORTRAN.
;       Johns Hopkins University Applied Physics Laboratory.
;       RES 18 Sep, 1989 --- converted to SUN
;
; Copyright (C) 1985, Johns Hopkins University/Applied Physics Laboratory
; This software may be used, copied, or redistributed as long as it is not
; sold and this copyright notice is reproduced on each copy made.  This
; routine is provided as is without any express or implied warranties
; whatsoever.  Other limitations apply as described in the file disclaimer.txt.
;-
;-------------------------------------------------------------

	function ymd2jd, iy, im, id, help=hlp

	if (n_params(0) LT 3) or keyword_set(hlp) then begin
	  print,' From Year, Month, and Day compute Julian Day number.'
	  print,' jd = ymd2jd(y,m,d)'
	  print,'   y = Year (like 1987).                    in'
	  print,'   m = month (like 7 for July).             in'
	  print,'   d = month day (like 23).                 in'
	  print,'   jd = Julian Day number (like 2447000).   out'
	  return, -1
	endif

	y = long(iy)
	m = long(im)
	d = long(id)
	jd = 367*y-7*(y+(m+9)/12)/4-3*((y+(m-9)/7)/100+1)/4 $
             +275*m/9+d+1721029

	return, jd

	end
;-------------------------------------------------------------
;+
; NAME:
;       WEEKDAY
; PURPOSE:
;       Compute weekday given year, month, day.
; CATEGORY:
; CALLING SEQUENCE:
;       wd = weekday(y,m,d,[nwd])
; INPUTS:
;       y, m, d = Year, month, day (Like 1988, 10, 31).      in
; KEYWORD PARAMETERS:
; OUTPUTS:
;       wd = Returned name of weekday.                       out
;       nwd = optional Weekday number.                       out
; COMMON BLOCKS:
; NOTES:
; MODIFICATION HISTORY:
;       R. Sterner. 31 Oct, 1988.
;       Johns Hopkins University Applied Physics Laboratory.
;       RES 18 Sep, 1989 --- converted to SUN
;
; Copyright (C) 1988, Johns Hopkins University/Applied Physics Laboratory
; This software may be used, copied, or redistributed as long as it is not
; sold and this copyright notice is reproduced on each copy made.  This
; routine is provided as is without any express or implied warranties
; whatsoever.  Other limitations apply as described in the file disclaimer.txt.
;-
;-------------------------------------------------------------

	FUNCTION WEEKDAY, Y, M, D, NWD, help=hlp

	IF (N_PARAMS(0) LT 3) or keyword_set(hlp) THEN BEGIN
	  PRINT,' Compute weekday given year, month, day.'
	  PRINT,' wd = weekday(y,m,d,[nwd])'
	  PRINT,'   y, m, d = Year, month, day (Like 1988, 10, 31).      in'
	  PRINT,'   wd = Returned name of weekday.                       out'
	  PRINT,'   nwd = optional Weekday number.                       out'
	  RETURN, -1
	ENDIF

	NAMES = ['','Sunday','Monday','Tuesday',$
		 'Wednesday','Thursday','Friday','Saturday']

	NWD = ((YMD2JD(Y,M,D) + 1) MOD 7) + 1
	RETURN, NAMES(NWD)

	END
;-------------------------------------------------------------
;+
; NAME:
;       STREP
; PURPOSE:
;       Edit a string by position. Precede, Follow, Replace, Delete.
; CATEGORY:
; CALLING SEQUENCE:
;       newstring = strep(string,cmd,p,ss,[iflg])
; INPUTS:
;       string = string to edit.                               in
;       cmd = edit command:                                    in
;         'P' = precede position p with substring ss.
;         'F' = follow position p with substring ss.
;         'R' = replace text starting at position p
;               with text from substring ss.
;         'D' = delete N characters starting at
;               position p.  The calling sequence for
;               this command is slightly different:
;               IFLG = STREP(string,'D',p,n,[iflg])
;               Where n = number of characters to delete.
;       p = character position to use.                         in
;           0 = first char.  Any number larger
;           than the string length = last char.
;       ss = substring to use.  For 'D' command                in
;            n is used instead of ss.
; KEYWORD PARAMETERS:
; OUTPUTS:
;       iflg = 0 for a successful edit,                        out
;       iflg = -1 for an error and no change to string.
;       newstring = edited string.                             out
; COMMON BLOCKS:
; NOTES:
; MODIFICATION HISTORY:
;       Written by R. Sterner, 27 Dec, 1984.
;       Converted to SUN 13 Aug, 1989 --- R. Sterner.
;       Johns Hopkins University Applied Physics Laboratory.
;
; Copyright (C) 1984, Johns Hopkins University/Applied Physics Laboratory
; This software may be used, copied, or redistributed as long as it is not
; sold and this copyright notice is reproduced on each copy made.  This
; routine is provided as is without any express or implied warranties
; whatsoever.  Other limitations apply as described in the file disclaimer.txt.
;-
;-------------------------------------------------------------

	function strep,s,cmd,ip,ss,iflg, help=hlp

	if (n_params(0) lt 4) or keyword_set(hlp) then begin
	  print,' Edit a string by position. Precede, Follow, Replace, Delete.'
	  print,' newstring = strep(string,cmd,p,ss,[iflg])
	  print,'   string = string to edit.                               in'
	  print,'   cmd = edit command:                                    in'
	  print,"     'P' = precede position p with substring ss.
	  print,"     'F' = follow position p with substring ss.
	  print,"     'R' = replace text starting at position p
	  print,'           with text from substring ss.
	  print,"     'D' = delete N characters starting at
	  print,'           position p.  The calling sequence for
	  print,'           this command is slightly different:
	  print,"           IFLG = STREP(string,'D',p,n,[iflg])
	  print,'           Where n = number of characters to delete.
	  print,'   p = character position to use.                         in'
	  print,'       0 = first char.  Any number larger
	  print,'       than the string length = last char.
	  print,"   ss = substring to use.  For 'D' command                in"
	  print,'        n is used instead of ss.
	  print,'   iflg = 0 for a successful edit,                        out'
	  print,'   iflg = -1 for an error and no change to string.
	  print,'   newstring = edited string.                             out'
	  return, -1
	endif

	N = STRLEN(S) - 1
	IF N LT 0 THEN $
	  IF CMD EQ 'D' THEN RETURN, '' ELSE RETURN, SS
	P = IP>0<N
	BS = BYTE(S)
	IF (CMD NE 'D') THEN  BSS = BYTE(SS)
	JFLG = 0

	CASE CMD OF
  'P':	BEGIN
	IF P EQ 0 THEN T = [BSS,BS] ELSE $
		T = [BS(0:P-1),BSS,BS(P:*)]
	END
  'F':	BEGIN
	IF P EQ N THEN BEGIN
	  T = [BS,BSS]
	ENDIF ELSE BEGIN
	  IF IP GE 0 THEN BEGIN
	    T = [BS(0:P),BSS,BS(P+1:*)]
	  ENDIF ELSE BEGIN
	    T = [BSS, BS]
	  ENDELSE
	ENDELSE
	END
  'R':  BEGIN
	NSS = STRLEN(SS)
	IF NSS GT N - P + 1 THEN $
		T = [BS(0:P-1),BSS] $
	ELSE BEGIN $
		T = BS
		T(P) = BSS
	ENDELSE
	END
  'D':	BEGIN
	ND = SS < (N + 1)
	IF P EQ 0 THEN $
	  IF ND EQ N+1 THEN T = '' ELSE $
	    T = [BS(ND:*)]
	IF P GT 0 THEN $
	  IF ND+P-1 GE N THEN $
	    T = [BS(0:P-1)] ELSE $
	    T = [BS(0:P-1),BS(ND+P:*)]
	END
  ELSE: JFLG = -1
  ENDCASE

	IF JFLG NE 0 THEN T = S
	IF JFLG EQ 0 THEN T = STRING(T)
	IF N_PARAMS(0) EQ 5 THEN IFLG = JFLG


	RETURN,T

	END
;-------------------------------------------------------------
;+
; NAME:
;       STRESS
; PURPOSE:
;       String edit by sub-string. Precede, Follow, Delete, Replace.
; CATEGORY:
; CALLING SEQUENCE:
;       new = stress(old,cmd,n,oldss,newss,ned)
; INPUTS:
;       old = string to edit.                               in
;       cmd = edit command:                                 in
;         'P' = precede.
;         'F' = follow.
;         'D' = delete.
;         'R' = replace.
;       n = occurrence number to process (0 = all).         in
;       oldss = reference substring.                        in
;       oldss may have any of the following forms:
;         1. s	  a single substring.
;         2. s...    start at substring s, end at end of string.
;         3. ...e    from start of string to substring e.
;         4. s...e   from subs s to subs e.
;         5. ...     entire string.
;       newss = substring to add. Not needed for 'D'        in
; KEYWORD PARAMETERS:
; OUTPUTS:
;       ned = number of occurrences actually changed.       out
;       new = resulting string after editing.               out
; COMMON BLOCKS:
; NOTES:
;       Notes: oldss and newss may be arrays.
; MODIFICATION HISTORY:
;       Written by R. Sterner, 6 Jan, 1985.
;       Johns Hopkins University Applied Physics Laboratory.
;       RES --- 23 May, 1988 fixed a bug in SSTYP = 2.
;       Converted to SUN 13 Aug, 1989 --- R. Sterner. (FOR loop change).
;       --- 8 Dec, 1992 added recursion so that OLDSS and NEWSS may be arrays
;       T.J.Harris, University of Adelaide.
;
; Copyright (C) 1985, Johns Hopkins University/Applied Physics Laboratory
; This software may be used, copied, or redistributed as long as it is not
; sold and this copyright notice is reproduced on each copy made.  This
; routine is provided as is without any express or implied warranties
; whatsoever.  Other limitations apply as described in the file disclaimer.txt.
;-
;-------------------------------------------------------------

	function stress,strng,cmdx,n,old_in,new_in,ned, help=hlp

	if (n_params(0) lt 3) or keyword_set(hlp) then begin
	  print,' String edit by sub-string. Precede, Follow, Delete, Replace.'
	  print,' new = stress(old,cmd,n,oldss,newss,ned)
	  print,'   old = string to edit.                               in'
	  print,'   cmd = edit command:                                 in'
	  print,"     'P' = precede.
	  print,"     'F' = follow.
	  print,"     'D' = delete.
	  print,"     'R' = replace.
	  print,'   n = occurrence number to process (0 = all).         in'
	  print,'   oldss = reference substring.                        in'
	  print,'   oldss may have any of the following forms:
	  print,'     1. s	  a single substring.
	  print,'     2. s...    start at substring s, end at end of string.
	  print,'     3. ...e    from start of string to substring e.
	  print,'     4. s...e   from subs s to subs e.
	  print,'     5. ...     entire string.
	  print,"   newss = substring to add. Not needed for 'D'        in"
	  print,'   ned = number of occurrences actually changed.       out'
	  print,'   new = resulting string after editing.               out'
	  print,' Notes: oldss and newss may be arrays.'
	  return, -1
	endif

	;--- if old_in an array then do the first element then call recursively
	old = old_in(0)
	if (n_elements(new_in) Gt 0) then new = new_in(0)

	cmd = strupcase(cmdx)
	pdot = strpos(old,'...')
	ssl = strlen(old)
	sstyp = 0
	pos1 = -1
	pos2 = -1
	rstr = strng
	if (pdot eq -1) then sstyp = 1
;	IF ((PDOT>0) EQ SSL-3) THEN SSTYP = 2
	if (pdot gt 0) and (pdot eq ssl-3) then sstyp = 2
	if (pdot eq 0) and (ssl gt 3) then sstyp = 3
	if (pdot gt 0) and (pdot lt ssl-3) then sstyp = 4
	if (pdot eq 0) and (ssl eq 3) then sstyp = 5
	ned = 0		; Number of occurrences actually changed.


	case sstyp of
1:	  begin
	    s = old
	    e = ''
	  end
2:	  begin
	    s = strsub(old,0,ssl-4)
	    e = ''
    	  end
3:  	  begin
	    s = ''
	    e = strsub(old,3,ssl-1)
	  end
4:  	  begin
	    s = strsub(old,0,pdot-1)
	    e = strsub(old,pdot+3,ssl-1)
	  end
5:  	  begin
	    s = ''
	    e = ''
	  end
else: 	  print, ' Error in STRESS: Error in sstyp'
	endcase


;---------------  Find substring # N start  ---------------
	pos = -1
	nfor = n>1
loop:
	for i = 1, nfor do begin
	  pos = pos + 1
	  case sstyp of
    1:      pos = strpos(rstr,s,pos)
    2:      pos = strpos(rstr,s,pos)
    4:      pos = strpos(rstr,s,pos)
    3:      pos = strpos(rstr,e,pos)
    5:      pos = 0
	  endcase
  	  if pos lt 0 then goto, done
	endfor

;----------  Find substring # N END  ----------------
    	case sstyp of
1:  	  begin
	    pos1 = pos
	    pos2 = pos + strlen(s) - 1
	  end
2:  	  begin
	    pos1 = pos
	    pos2 = strlen(rstr) - 1
	  end
3:  	  begin
	    pos1 = 0
	    pos2 = pos + strlen(e) - 1
	  end
4:  	  begin
	    pos1 = pos
	    pos2 = strpos(rstr,e,pos+1)
	    if (pos2 lt 0) then goto, done
	    pos2 = pos2 + strlen(e) - 1
	  end
5:  	  begin
	    pos1 = 0
	    pos2 = strlen(rstr) - 1
	  end
	endcase

;------------  edit string  --------------
    	case cmd of
'P':  	  begin
	    rstr = strep(rstr,cmd,pos1,new)
	    pos = pos + strlen(new)
	  end
'F':  	  begin
	    rstr = strep(rstr,cmd,pos2,new)
	    pos = pos + strlen(new)
	  end
'R':  	  begin
	    rstr = strep(rstr,'D',pos1,pos2-pos1+1)
	    if (pos1 gt 0) then $
	      rstr = strep(rstr,'F',pos1-1,new)
	    if (pos1 eq 0) then $
	      rstr = strep(rstr,'P',0,new)
	    pos = pos + strlen(new) - 1
	  end
'D':  	  begin
	    rstr = strep(rstr,cmd,pos1,pos2-pos1+1)
	    pos = pos - 1
	  end
else: 	  begin
	    print, 'Error in STRESS: unknown command.'
	    return,rstr
	  end
endcase

	ned = ned + 1
	if sstyp eq 5 then return,rstr
	if n eq 0 then goto, loop

done:

	;--- if old_in an array then do the first element then call recursively
	;--- and accumulate the results
	if (n_elements(old_in) gt 1) then begin	;call again until done all
		old = old_in(1:*)
		if (n_elements(new_in) gt 1) then new = new_in(1:*)
		tmp = 0
		rstr = stress(rstr,cmdx,n,old,new,tmp)
		ned = ned+tmp
	endif
	return, rstr
	end
;-------------------------------------------------------------
;+
; NAME:
;       YMD2DATE
; PURPOSE:
;       Convert from year, month, day numbers to date string.
; CATEGORY:
; CALLING SEQUENCE:
;       date = ymd2date(Y,M,D)
; INPUTS:
;       y = year number (like 1986).                         in
;       m = month number (1 - 12).                           in
;       d = day of month number (1 - 31).                    in
; KEYWORD PARAMETERS:
;       Keywords:
;         FORMAT = format string.  Allows output date to be customized.
;            The following substitutions take place in the format string:
;         Y$ = 4 digit year.
;         y$ = 2 digit year.
;         N$ = full month name.
;         n$ = 3 letter month name.
;         d$ = day of month number.
;         W$ = full weekday name.
;         w$ = 3 letter week day name.
; OUTPUTS:
;       date = returned date string (like 24-May-1986).      out
; COMMON BLOCKS:
; NOTES:
;       Notes:
;         The default format string is 'd$-n$-Y$' giving 24-Sep-1989
;         Example: FORMAT='w$ N$ d$, Y$' would give 'Mon
; MODIFICATION HISTORY:
;       R. Sterner.  16 Jul, 1986.
;       RES 18 Sep, 1989 --- converted to SUN
;       R. Sterner, 28 Feb, 1991 --- modified format.
;       R. Sterner, 16 Dec, 1991 --- added space to 1 digit day.
;       Johns Hopkins University Applied Physics Laboratory.
;
; Copyright (C) 1986, Johns Hopkins University/Applied Physics Laboratory
; This software may be used, copied, or redistributed as long as it is not
; sold and this copyright notice is reproduced on each copy made.  This
; routine is provided as is without any express or implied warranties
; whatsoever.  Other limitations apply as described in the file disclaimer.txt.
;-
;-------------------------------------------------------------

	function ymd2date, y, m, d, help=hlp, format=frmt

	if (n_params(0) lt 3) or keyword_set(hlp) then begin
	  print,' Convert from year, month, day numbers to date string.'
	  print,' date = ymd2date(Y,M,D)'
	  print,'   y = year number (like 1986).                         in'
	  print,'   m = month number (1 - 12).                           in'
	  print,'   d = day of month number (1 - 31).                    in'
	  print,'   date = returned date string (like 24-May-1986).      out'
	  print,' Keywords:'
	  print,'   FORMAT = format string.  Allows output date to be '+$
	    'customized.'
	  print,'      The following substitutions take place in the '+$
	    'format string:'
	  print,'   Y$ = 4 digit year.'
	  print,'   y$ = 2 digit year.'
	  print,'   N$ = full month name.'
	  print,'   n$ = 3 letter month name.'
	  print,'   d$ = day of month number.'
	  print,'   W$ = full weekday name.'
	  print,'   w$ = 3 letter week day name.'
	  print,' Notes:'
	  print,"   The default format string is 'd$-n$-Y$' giving 24-Sep-1989"
	  print,"   Example: FORMAT='w$ N$ d$, Y$' would give 'Mon "+$
	    "September 18, 1989'"
	  return, -1
	endif

	;---- error check -----
	w = where(y lt 0, cnt)
	if cnt gt 0 then begin
	  print,'Error in ymd2date: invalid year: ',y(w)
	  return, -1
	endif
	;-----  Handle 2 digit years  ------
	w = where(y lt 50, cnt)			; Y < 50 assumed 2xxx.
	if cnt gt 0 then y(w) = y(w) + 2000
	w = where(y lt 100, cnt)		; 50 < Y < 100 assumed 19xx.
	if cnt gt 0 then y(w) = y(w) + 1900
	w = where((m lt 1) or (m gt 12),cnt)
	if cnt gt 0 then begin
	  print,'Error in ymd2date: invalid month: ',m(w)
	  return, -1
	endif
	w = where((d lt 1) or (d gt 31), cnt)
	if cnt gt 0 then begin
	  print,'Error in ymd2date: invalid month day: ', d(w)
	  return, -1
	endif

	;-----  format string  ------
	fmt = 'd$-n$-Y$'
	if keyword_set(frmt) then fmt = frmt

	l_y = n_elements(y)-1
	l_m = n_elements(m)-1
	l_d = n_elements(d)-1
	l_dates = l_y>l_m>l_d
	date_arr = strarr(l_dates+1)

	;-----  Loop through all dates  ---------
	for i = 0, l_dates do begin

	  ;-----  Get all the allowed parts  -----
	  yu = strtrim(y(i<l_y),2)
	  yl = strtrim(fix(y(i<l_y)-100*fix(y(i<l_y)/100)),2)
	  mnames = mnthnmes()
	  mu = mnames(m(i<l_m))
	  ml = strmid(mu,0,3)
	  dl = strtrim(d(i<l_d),2)
	  if strlen(dl) eq 1 then dl = ' '+dl	; Add space to 1 digit day.
	  wu = weekday(y(i<l_y),m(i<l_m),d(i<l_d))
	  wl = strmid(wu,0,3)

	  ;----  Do substitutions  ------
	  date = fmt
	  date = stress(date, 'R', 0, 'Y$', yu)	; 4 digit year.
	  date = stress(date, 'R', 0, 'y$', yl)	; 2 digit year.
	  date = stress(date, 'R', 0, 'd$', dl)	; day of month.
	  date = stress(date, 'R', 0, 'N$', mu)	; Full month name.
	  date = stress(date, 'R', 0, 'n$', ml)	; 3 letter month name.
	  date = stress(date, 'R', 0, 'W$', wu)	; Full weekday name.
	  date = stress(date, 'R', 0, 'w$', wl)	; 3 letter weekday name.

	  date_arr(i) = date
	endfor

	if l_dates eq 0 then date_arr=date_arr(0)  ; Return scalars as scalars.

	return, date_arr

	end
;-------------------------------------------------------------
;+
; NAME:
;       YDN2DATE
; PURPOSE:
;       Convert year and day of the year to a date string.
; CATEGORY:
; CALLING SEQUENCE:
;       date = ydn2date(Year, dn)
; INPUTS:
;       Year = year.                      in
;       dn = day of the year.             in
; KEYWORD PARAMETERS:
;       Keywords:
;         FORMAT = format string.  (see ymd2date).
; OUTPUTS:
;       date = returned date string.      out
;              (like 86-APR-25).
; COMMON BLOCKS:
; NOTES:
; MODIFICATION HISTORY:
;       Ray Sterner,    25 APR, 1986.
;       Johns Hopkins University Applied Physics Laboratory
;       R. Sterner, 1994 May 27 --- Renamed from dn2date.
;
; Copyright (C) 1986, Johns Hopkins University/Applied Physics Laboratory
; This software may be used, copied, or redistributed as long as it is not
; sold and this copyright notice is reproduced on each copy made.  This
; routine is provided as is without any express or implied warranties
; whatsoever.  Other limitations apply as described in the file disclaimer.txt.
;-
;-------------------------------------------------------------

	function ydn2date, yr, dn, help=hlp, format=frmt

	if (n_params(0) lt 2) or keyWord_set(hlp) then begin
	  print,' Convert year and day of the year to a date string.'
	  print,' date = ydn2date(Year, dn)'
	  print,'   Year = year.                      in'
	  print,'   dn = day of the year.             in'
	  print,'   date = returned date string.      out'
	  print,'          (like 86-APR-25).
	  print,' Keywords:'
	  print,'   FORMAT = format string.  (see ymd2date).'
	  return, -1
	endif

	ydn2md,yr,dn,m,d
	if m lt 0 then begin
	  print,' Error in month in dn2date.'
	  m = 0
	endif
	return, ymd2date(yr,m,d,format=frmt)

	end
;+
;* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
;
; ROUTINE:    rdCCDAdi
;
; AUTHOR:    Chuck Chaapel, STC-METSAT, 3/20/96
;
; USAGE:    called from disp
;
; PURPOSE:    read & interpret CCDA formatted NVAP data files
;
; INPUT:     none
;
; OUTPUT:    file data in arrays
;
; LIMITATIONS:
;
;* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
;-

;-------------------------------------------------------------------------------
;    EVENT HANDLER FOR DATA FIELD PICKER
;-------------------------------------------------------------------------------
PRO ArrayChoice_event, event

common data, data_exists, description, dataArray, headerArray, titleArray, unitsArray, $
             commentArray, numFields, fieldNum
common main_butts, select_button, save_button, quit_button

    WIDGET_CONTROL, event.top, GET_UVALUE=description

    CASE event.id OF

        DESCRIPTION.DONE: begin
           WIDGET_CONTROL, select_button, sensitive=1
            WIDGET_CONTROL, quit_button, sensitive=1
            WIDGET_CONTROL, event.top, /DESTROY
        end

        ELSE: begin

            fieldNum = event.index

            title = STRTRIM(description.title(fieldNum))
            units = STRTRIM(description.units(fieldNum))
            comment = STRTRIM(description.comment(fieldNum))
;
            read_CCDA_data
            ne_img,dataArray,xSize=description.iSize,$
                ySize=description.jSize,title=title,$
                units=units,comment=comment
        end
    ENDCASE
END

;--------------------------------------------------------
;displays the color bar in a new window
;--------------------------------------------------------
Pro dispclrbar
buf=bytarr(472,20)

close,20
openr,20,'colorbar.img'
readu,20,buf
close,20
window,5, xsize = 470, ysize = 20,title="Colorbar"
  tv,buf
end
;
;-------------------------------------------------------------------------------
;    ROUTINE TO READ 1 CCDA DATA FIELD
;-------------------------------------------------------------------------------
PRO read_CCDA_data

common data, data_exists, description, dataArray, headerArray, titleArray, $
             unitsArray, commentArray, numFields, fieldNum
common display_scale, data_max, data_type
common dave_stuff, datafile, pixelfile, hfield
common zoom_stuff, izx,izy,izfac,mapclr, mapcent, imgsize, imgdispnum

; Declare variables

    header = BYTARR(144)

    tapeCode = ''
    sourceCode = ''
    paramCode = 0
    dataType = 0
    blanks = ''
    iy2k1 = 0
    iy2k2 = 0
    startYear = 0
    startDay = 0
    startHour = 0
    endYear = 0
    endDay = 0
    iSize = 0
    jSize = 0
    endHour = 0
    deltaLon = 0.
    deltaLat = 0.
    firstLat = 0.
    firstLon = 0.
    offset = 0.
    scale = 0.
    zindef = 0.
    label = ''
    mapcent = 180
    imgdispnum = 0

    nrecbyte = description.iSize * 2
    OPENR, unit, datafile, /GET_LUN
;
;skip to correct field to read
;
    bskip = LONG((LONG(nrecbyte)+(LONG(description.iSize)*LONG(description.jSize)*2))*fieldNum)
    point_lun,unit,bskip
;
; Read header record
;
    numpad = nrecbyte - 144
    if(numpad gt 0) then begin
         pad1 = bytarr(numpad)
         READU, unit, header,pad1
    endif else begin
         READU, unit, header
    endelse

    headerString = STRING(header)
    READS, headerString, tapeCode, sourceCode, paramCode, dataType, blanks,$
        iy2k1, iy2k2, startYear, startDay, startHour, endYear, endDay, $
        endHour, iSize, jSize, deltaLon, deltaLat, $
        firstLat, firstLon, OFFSET, SCALE, ZINDEF, $
        blanks, label, $
        FORMAT = '(A4,I3,I3,I1,A1,I2,I2,I2,I3,I2,I2,I3,I2,I4,I4,F6.2,F6.2,' $
        +   'F7.3,F8.3,E11.5,E11.5,E11.5,A6,A40)'

; set correct year/century string

    if(iy2k1 eq 0) then begin
         iy2k1 = 19
         iy2k2 = 19
    endif
    startYear = iy2k1*100 + startYear
    endYear   = iy2k2*100 + endYear

; set map center

    if(firstLon lt 0) then mapcent = 0

; Read data array

    data = INTARR(iSize,jSize)
    dataArray = FLTARR(iSize,jSize)
    READU, unit, data

;Close file

    FREE_LUN, unit
;
;Byte swap some early (88-95) SSM/I grids (lwp, clw, pwc)

    if(dataType eq 7) then BYTEORDER, data

;.................................
;Check for OS type and whether byte swapping is needed

	osf = !version.os_family
    print,'operating system family: ',osf
    if(osf eq 'UNIX' or osf eq 'unix') then BYTEORDER, data
    if(osf eq 'MacOS')                 then BYTEORDER, data
;.................................

    dataArray = (SCALE * FLOAT(data)) + OFFSET
    windex = WHERE(data eq ZINDEF,wcount)
    if(wcount NE 0) then  begin
       dataArray(Where(data eq ZINDEF)) = 999.9
    endif

;Process text

    title = STRCOMPRESS(datafile)

    startT = ydn2date(startYear,startDay,format='n$ d$ Y$') + '  ' +  $
             strcompress(STRING(startHour),/remove_all) + 'Z'
    endT = ydn2date(endYear,endDay,format='n$ d$ Y$') + '  ' +  $
             strcompress(STRING(endHour),/remove_all) + 'Z'
    units = startT + '  -  ' + endT + '  ' + STRCOMPRESS(label)

    comment = tapeCode + ' ' + sourceCode

    RETURN
END

;-------------------------------------------------------------------------------
;    ROUTINE TO READ THE NEXT CCDA HEADER AND POSITION AT NEXT HEADER
;-------------------------------------------------------------------------------
PRO read_CCDA_header, unit, header, iSize, jSize, title, units, comment
common dave_stuff, datafile,pixelfile, hfield
; Declare variables

    header = BYTARR(144)

    tapeCode = ''
    sourceCode = ''
    paramCode = 0
    dataType = 0
    blanks = ''
    iy2k1 = 0
    iy2k2 = 0
    startYear = 0
    startDay = 0
    startHour = 0
    endYear = 0
    endDay = 0
    endHour = 0
    iSize = 0
    jSize = 0
    deltaLon = 0.
    deltaLat = 0.
    firstLat = 0.
    firstLon = 0.
    offset = 0.
    scale = 0.
    zindef = 0.
    label = ''

;
; Read header record

    READU, unit, header
    headerString = STRING(header)
    READS, headerString, tapeCode, sourceCode, paramCode, dataType, blanks,$
        iy2k1, iy2k2, startYear, startDay, startHour, endYear, endDay, $
        endHour, iSize, jSize, deltaLon, deltaLat, $
        firstLat, firstLon, OFFSET, SCALE, ZINDEF, $
        blanks, label, $
        FORMAT = '(A4,I3,I3,I1,A1,I2,I2,I2,I3,I2,I2,I3,I2,I4,I4,F6.2,F6.2,' $
        +   'F7.3,F8.3,E11.5,E11.5,E11.5,A6,A40)'

    if(iy2k1 eq 0) then begin
         iy2k1 = 19
         iy2k2 = 19
    endif
    startYear = iy2k1*100 + startYear
    endYear   = iy2k2*100 + endYear

;Process text

    title = STRCOMPRESS(datafile)

    startT = ydn2date(startYear,startDay,format='n$ d$ Y$') + '  ' + $
             strcompress(STRING(startHour),/remove_all) + 'Z'
    endT = ydn2date(endYear,endDay,format='n$ d$ Y$') + '  ' + $
             strcompress(STRING(endHour),/remove_all) + 'Z'
    units = startT + '  -  ' + endT + '      ' + STRCOMPRESS(label)
    comment = tapeCode + ' ' + sourceCode

; Position at next header

    nrecbyte = iSize * 2
    bskip = LONG((Long(nrecbyte)+(LONG(iSize)*LONG(jSize)*2))*hfield)
    point_lun,unit,bskip

    RETURN
END
;
;-------------------------------------------------------------------------------
;    MAIN ROUTINE TO READ CCDA DATA FILES
;-------------------------------------------------------------------------------
PRO rdCCDAdi,filename,pixname

common main_butts, select_button, save_button, quit_button
common main_message, message_box
common dave_stuff, datafile,pixelfile,hfield
common data, data_exists, description, dataArray, headerArray, titleArray, $
             unitsArray, commentArray, numFields, fieldNum
common data_stuff, datamn, datamx, immset, fdatamn, fdatamx
common zoom_stuff, izx,izy,izfac,mapclr, mapcent, imgsize, imgdispnum

    fieldNum = 0
    immset = 0
    imgsize = 720.
    imgdispnum = 0
    datafile = filename
    pixelfile = pixname
    OPENR, unit, datafile, /GET_LUN

    Widget_Control, /HOURGLASS
;
; **** FIRST READ HEADERS OF ALL DATA IN FIELD *************************
;
    numFields = 0
    hfield = 1
    message = 'Reading data header for field '+STRING(numFields+1)
    message = STRCOMPRESS(message)
    widget_control,message_box,set_value=message
    read_CCDA_header, unit, header, iSize, jSize, title, units, comment
    headerArray = [header]
    dataarray = [iSize,jSize]
    titleArray = [title]
    unitsArray = [units]
    commentArray = [comment]
    numFields = numFields + 1
    hfield = hfield + 1

    WHILE NOT EOF(unit) DO BEGIN
        message = 'Reading data header for field '+STRING(numFields+1)
        message = STRCOMPRESS(message)
        widget_control,message_box,set_value=message
        read_CCDA_header, unit, header, iSize, jSize, title, units, comment
        headerArray = [headerArray, header]
        titleArray = [titleArray, title]
        unitsArray = [unitsArray, units]
        commentArray = [commentArray, comment]
        numFields = numFields + 1
        hfield = hfield + 1
    END
    FREE_LUN, unit
;
; **** LIST FIELD INFO AND GET SELECTION *****************************
;
    if(numFields ge 1) then data_exists=1 else data_exists=0

    widget_control,message_box,set_value='Generating data field listing ...'

    buttonNames = unitsArray

    FILEBRK, datafile, FILE=fName
    base = WIDGET_BASE(TITLE=fName, /COLUMN)
    picker_box = base
    text = WIDGET_LABEL(base, VALUE=title)
    text = WIDGET_LABEL(base, VALUE=STRCOMPRESS(STRING(numFields) + $
        ' data fields were read'))
    text = WIDGET_LABEL(base, VALUE='Choose a data field to Display')
    List = Widget_List(base, VALUE = buttonNames, YSIZE=24)
    button = Widget_Button(base, Value='Back to File Select or Quit')

    description = {data:dataarray, header:headerArray, $
        iSize:iSize, jSize:jSize,$
        title:titleArray,units:unitsArray, $
        comment:commentArray,done:button}

    WIDGET_CONTROL, base, SET_UVALUE=description
    WIDGET_CONTROL, /REALIZE, base

    XMANAGER, 'ArrayChoice', base

    WIDGET_CONTROL, select_button, sensitive=0
    WIDGET_CONTROL, quit_button, sensitive=0
    WIDGET_CONTROL,message_box,set_value='                         '
;
END

PRO ccdaglb,work_data,Firstlat,deltaLat,deltaLon,iSize,jSize,globalave

;  this procedure produces the global and hemispheric averages
;  from the ccda formatted fields.  These are true area weighted
;  averages!!
;
;  written by dave randel cira/csu
;          on july 6, 1992
;   converted april 1997 to an idl procedure

   nsx = INTARR(3)
   nex = INTARR(3)
   fact = FLTARR(360)

   jSize_2 = fix( float(jSize) / 2.)
   nsx(0) = 0
   nsx(1) = jSize_2
   nsx(2) = 0
   nex(0) = jSize_2-1
   nex(1) = jSize-1
   nex(2) = jSize-1

;***  define area scaling factors ********

   theta = Firstlat
   qcons = 3.14159/180.

   for j = nsx(0),nex(0) do begin
      fact(j)=(SIN(qcons*theta)-SIN(qcons*(theta+deltaLat)) )
      theta = theta + deltaLat
   endfor

   for j = nsx(1), nex(1) do begin
      fact(j) = fact(nex(1) - j)
   endfor

;*** sum up zones applying weighting ********

   for m = 0,2 do begin
     sum = 0.
     globalave(m) = 0.
     for  j = nsx(m),nex(m) do begin
       for i = 0,iSize-1 do begin
        if(work_data(i,j) ne 999.9)  then begin
             sum = sum + fact(j)
        endif
       endfor
     endfor

     for j = nsx(m),nex(m) do begin
       rmult =   fact(j) / sum
       for i = 0,iSize-1 do begin
         if(work_data(i,j) ne 999.9) then begin
              globalave(m) = (work_data(i,j) * rmult) + globalave(m)
         endif
       endfor
     endfor
   endfor

END
;-------------------------------------------------------------
;+
; NAME:
;       YDN2MD
; PURPOSE:
;       Convert from year and day number of year to month and day of month.
; CATEGORY:
; CALLING SEQUENCE:
;       ydn2md,yr,dy,m,d
; INPUTS:
;       yr = year (like 1988).               in
;       dy = day number in year (like 310).  in
; KEYWORD PARAMETERS:
; OUTPUTS:
;       m = month number (like 11 = Nov).    out
;       d = day of month (like 5).           out
; COMMON BLOCKS:
; NOTES:
;       Note: On error returns m = d = -1.
; MODIFICATION HISTORY:
;       R. Sterner 20 June, 1985 (for budget workspace).
;       Johns Hopkins University Applied Physics Laboratory.
;       RES 18 Sep, 1989 --- converted to SUN
;
; Copyright (C) 1985, Johns Hopkins University/Applied Physics Laboratory
; This software may be used, copied, or redistributed as long as it is not
; sold and this copyright notice is reproduced on each copy made.  This
; routine is provided as is without any express or implied warranties
; whatsoever.  Other limitations apply as described in the file disclaimer.txt.
;-
;-------------------------------------------------------------

	PRO YDN2MD,YR,DY,M,D, help=hlp

	IF (N_PARAMS(0) LT 4) or keyword_set(hlp) THEN BEGIN
	  PRINT,' Convert from year and day number of year to month '+$
	    'and day of month.'
	  PRINT,' ydn2md,yr,dy,m,d'
	  PRINT,'   yr = year (like 1988).               in'
	  PRINT,'   dy = day number in year (like 310).  in'
	  PRINT,'   m = month number (like 11 = Nov).    out'
	  PRINT,'   d = day of month (like 5).           out'
	  PRINT,' Note: On error returns m = d = -1.'
	  RETURN
	ENDIF

	; Days before start of each month.
	YDAYS = [0,31,59,90,120,151,181,212,243,273,304,334,366]

	; Correct YDAYS for leap-year.
	IF (((YR MOD 4) EQ 0) AND ((YR MOD 100) NE 0)) $
            OR ((YR MOD 400) EQ 0) THEN YDAYS(2) = YDAYS(2:*) + 1

	FOR I = 1, 12 DO BEGIN
	  IF DY LE YDAYS(I) THEN GOTO, NEXT
	ENDFOR

	PRINT,' ydn2md: error in day number.'
	M = -1
	D = -1
	RETURN

NEXT:	M = I
	D = DY - YDAYS(M-1)
	RETURN

	END
PRO DEF_CLRS

COMMON ColorScheme_COM, nColors, black, white

; Define color table

	nColors = !D.N_COLORS     ; total number of color indices available
    if nColors GT 236 then nColors = 236   ;set number of colors
	nColors = nColors-2       ; leave space for black & white

	nRainbow = 19             ; Use a 19 color rainbow to delineate values
	mult = nColors/nRainbow   ; There are mult sub-shades per major color

	IF mult LT 2 THEN BEGIN
		sd_xhelp, ['Not enough colors are available from the X server!', $
		'Try quitting other color-hog applications and then', $
		'restart idl.']
		EXIT
	ENDIF

	red = BYTE([150,195,0,0,1,0,0,0,32,113,178,255,255,255, $
		255,255,255,255,255])
	green = BYTE([0,0,0,0,125,206,255,228,246,222,252,255,227, $
		199,171,133,85,0,0])
	blue = BYTE([150,221,191,255,255,255,255,181,112, $
		0,0,0,0,0,0,0,70,0,146])

; form the all color table indices plus black & white

	white = 255B
	black = 0B
	red   = [CONGRID(red,   nColors, /interp, /minus_one), black, white]
	green = [CONGRID(green, nColors, /interp, /minus_one), black, white]
	blue  = [CONGRID(blue,  nColors, /interp, /minus_one), black, white]

; Set names and load color table

	black = nColors - 1
	white = nColors - 2
	TVLCT,  red, green, blue

END


pro labelstring
    common zoom_stuff, izx,izy,izfac,mapclr,mapcent,imgsize
    common data, data_exists, description, dataArray, headerArray, titleArray, $
             unitsArray, commentArray, numFields, fieldNum

    title = STRTRIM(description.units(fieldNum))
    newstring = '            '
    datestring = '            '
    str1 = STRMID(title,0,3)

    if(str1 eq 'Jan') then str1 = '  1'
    if(str1 eq 'Feb') then str1 = '  2'
    if(str1 eq 'Mar') then str1 = '  3'
    if(str1 eq 'Apr') then str1 = '  4'
    if(str1 eq 'May') then str1 = '  5'
    if(str1 eq 'Jun') then str1 = '  6'
    if(str1 eq 'Jul') then str1 = '  7'
    if(str1 eq 'Aug') then str1 = '  8'
    if(str1 eq 'Sep') then str1 = '  9'
    if(str1 eq 'Oct') then str1 = ' 10'
    if(str1 eq 'Nov') then str1 = ' 11'
    if(str1 eq 'Dec') then str1 = ' 12'

    str2 = STRMID(title,7,4)
    STRPUT,newstring,str1,0
    STRPUT,newstring,'/',3
    STRPUT,newstring,str2,4

    datestring = '         '
    str1 = STRMID(title,0,3)
    date = STRMID(title,4,2)
    str2 = STRMID(title,9,2)
    STRPUT,datestring,str1,0
    STRPUT,datestring,' ',3
    STRPUT,datestring,date,4
    STRPUT,datestring,' ',6
    STRPUT,datestring,str2,7
    xyouts,2,5,datestring,charsize=2,color=mapclr,font=-1,/device

END


;------------------------------------------------------------------
;  Procedure dispmap plots a map on full image centered at 0 or 180
;------------------------------------------------------------------


pro dispmap
;    common zoom_stuff, mapclr,imgdispnum
     common zoom_stuff, izx,izy,izfac,mapclr,mapcent,imgsize

    map_set,/cylindrical,0,mapcent,/noerase,/grid,$
            /noborder,e_grid={color:mapclr},xmargin=0,ymargin=0.
    map_continents,color=mapclr

end


;------------------------------------------------------------------
;  Procedure zoommap plots a map on the zoomed 15x15 image
;------------------------------------------------------------------

pro zoommap, blat,blon,latinc,loninc
        common zoom_stuff, izx,izy,izfac,mapclr,mapcent,imgsize

    elat = blat + (15*latinc)
    elon = blon + (15*loninc)

    map_set,/cylindrical,0,0,/noerase,/grid,e_grid={color:mapclr},$
            limit=[blat,blon,elat,elon],xmargin=0,ymargin=0
    map_continents,/coasts,/hires,color=mapclr

end


;-------------------------------------------------------------
;+
; NAME:
;       FILEBREAK
; PURPOSE:
;       Breaks file name(s) into components.
; CATEGORY:
; CALLING SEQUENCE:
;       filebreak, input
; INPUTS:
;       input = input file name (may be an array).  in
; KEYWORD PARAMETERS:
;       Keywords:
;         DIRECTORY=d  returned directory name.
;         FILE=f  returned complete file name (without directory).
;         NVFILE=fnv  returned complete file name without version.
;         NAME=n  returned file name without ext or vers.
;         EXTENSION=e  returned file extension.
;         VERSION=v  returned file version number.
;         OS=os  Input operating system name if not the
;           one for the current IDL session.  Values may be:
;           vms = Vax VMS, dos = PC Dos, anything else is unix.
;         The following diagram show relations between components:
;
;        . . . A A A / N N N N N N . E E E E ; V V V
;
;       |             |           | |       | |     |
;       |    DIR      |   NAME    | |  EXT  | | VER |
;       +-------------+-----------+ +-------+ +-----+
;       |             |                     |       |
;       |             |        NVFILE       |       |
;       |             +---------------------+       |
;       |             |                             |
;       |             |              FILE           |
;       |             +-----------------------------+
;       |                                           |
;       |                  INPUT                    |
;       +-------------------------------------------+
;
; OUTPUTS:
; COMMON BLOCKS:
; NOTES:
;       Notes: The argument to this routine has the form:
;         dir+file where dir is operating system dependent
;         but something like d0:[aaa.bbb] for vms, or
;         /aaa.bbb/ for unix, or d:\aaa.bbb\ for DOS.
;         The file will be of the form: name.ext;vers.
;         Only VMS has version numbers.
;         Requested values that do not occur are returned as
;         null strings
; MODIFICATION HISTORY:
;       Ray Sterner,  16 APR, 1985.
;       Johns Hopkins University Applied Physics Laboratory.
;       RES, Added DIR 29 May, 1985.
;       R. Sterner, made op. sys. independent --- 11 Sep, 1991.
;
; Copyright (C) 1985, Johns Hopkins University/Applied Physics Laboratory
; This software may be used, copied, or redistributed as long as it is not
; sold and this copyright notice is reproduced on each copy made.  This
; routine is provided as is without any express or implied warranties
; whatsoever.  Other limitations apply as described in the file disclaimer.txt.
;-
;-------------------------------------------------------------

	PRO FILEBRK, pathfile, directory=dir, file=file, nvfile=nvfile, $
	  name=name, extension=ext, version=vers, os=os, help=hlp

	IF (N_PARAMS(0) EQ 0) or keyword_set(hlp) THEN BEGIN
	  PRINT,' Breaks file name(s) into components.
	  PRINT,' filebreak, input'
	  print,'   input = input file name (may be an array).  in'
	  print,' Keywords:'
	  print,'   DIRECTORY=d  returned directory name.'
	  print,'   FILE=f  returned complete file name (without directory).'
	  print,'   NVFILE=fnv  returned complete file name without version.'
	  print,'   NAME=n  returned file name without ext or vers.'
	  print,'   EXTENSION=e  returned file extension.'
	  print,'   VERSION=v  returned file version number.'
	  print,'   OS=os  Input operating system name if not the'
	  print,'     one for the current IDL session.  Values may be:'
	  print,'     vms = Vax VMS, dos = PC Dos, anything else is unix.'
	  print,'   The following diagram show relations between components:'
	  print,' '
          print,'  . . . A A A / N N N N N N . E E E E ; V V V
	  print,' '
          print,' |             |           | |       | |     |
          print,' |    DIR      |   NAME    | |  EXT  | | VER |
          print,' +-------------+-----------+ +-------+ +-----+
          print,' |             |                     |       |
          print,' |             |        NVFILE       |       |
          print,' |             +---------------------+       |
          print,' |             |                             |
          print,' |             |              FILE           |
          print,' |             +-----------------------------+
          print,' |                                           |
          print,' |                  INPUT                    |
          print,' +-------------------------------------------+
	  print,' '
	  print,' Notes: The argument to this routine has the form:'
	  print,'   dir+file where dir is operating system dependent'
	  print,'   but something like d0:[aaa.bbb] for vms, or'
	  print,"   /aaa.bbb/ for unix, or d:\aaa.bbb\ for DOS."
	  print,'   The file will be of the form: name.ext;vers.'
	  print,'   Only VMS has version numbers.'
	  print,'   Requested values that do not occur are returned as'
	  print,'   null strings'
	  RETURN
	ENDIF

	;---  Allow input to be an array  ------
	n = n_elements(pathfile)

	;------  By default all parts of the path+file are null strings ---
	dir = strarr(n)
	file = strarr(n)
	nvfile = strarr(n)
	name = strarr(n)
	ext = strarr(n)
	vers = strarr(n)

	;---  Loop through each input element  ---
	for i = 0, n-1 do begin

	  ;-------  The path+file was null  -----
	  if pathfile(i) ne '' then begin

	    ;-------  Find where to split directory and file name  ------
	    if n_elements(os) eq 0 then os = !version.os
	    os = strupcase(os)

	    case os of
'VMS':	    begin
	      file(i) = pathfile(i)
	      loc = strpos(pathfile(i),']')
	      if loc eq -1 then loc = strpos(pathfile(i),':')
	    end
'WINDOWS': begin
	      file(i) = pathfile(i)
	      loc = strpos(strtrim(reverse(byte(pathfile(i))),2),'\')
	      if loc ge 0 then loc = strlen(pathfile(i))-loc-1
	    end
'MACOS':   begin
	      file(i) = pathfile(i)
	      loc = strpos(strtrim(reverse(byte(pathfile(i))),2),':')
	      if loc ge 0 then loc = strlen(pathfile(i))-loc-1
	    end
else:	    begin	; Assume UNIX.
	      file(i) = pathfile(i)
	      loc = strpos(strtrim(reverse(byte(pathfile(i))),2),'/')
	      if loc ge 0 then loc = strlen(pathfile(i))-loc-1
	    end
	    endcase

	    ;---  If directory exists split directory and rest of file name ---
	    if loc ge 0 then begin
	      dir(i) = strmid(pathfile(i),0,loc+1)
	      file(i) = strmid(pathfile(i),loc+1,999)
	    endif

	    ;---  If version exists split version and rest of file name  ---
	    nvfile(i) = file(i)
	    loc = strpos(file(i),';')
	    if loc ge 0 then begin
	      nvfile(i) = strmid(file(i),0,loc)
	      vers(i) = strmid(file(i),loc+1,999)
	    endif

	    ;---  If extension exists split extension and file name  ---
	    name(i) = nvfile(i)
	    loc = strpos(nvfile(i),'.')
	    if loc ge 0 then begin
	      name(i) = strmid(nvfile(i),0,loc)
	      ext(i) = strmid(nvfile(i),loc+1,999)
	    endif

	  endif  ; Endif name not null.

	endfor  ; End of loop through input elements.

	;---  Check if scalars  -----
 	if n_elements(dir) eq 1 then dir = dir(0)
 	if n_elements(file) eq 1 then file = file(0)
 	if n_elements(nvfile) eq 1 then nvfile = nvfile(0)
 	if n_elements(name) eq 1 then name = name(0)
 	if n_elements(ext) eq 1 then ext = ext(0)
 	if n_elements(vers) eq 1 then vers = vers(0)


	return
	end



 PRO nextprev,nxpre
    common data, data_exists, description, dataArray, headerArray, titleArray, $
             unitsArray, commentArray, numFields, fieldNum

    if(nxpre eq 1) then begin
         fieldNum = fieldNum + 1
         if(fieldNum gt numFields-1) then fieldNum = 0
    endif else begin
         fieldNum = fieldNum - 1
         if(fieldNum lt 0) then fieldNum = numFields-1
    endelse

    title = STRTRIM(description.title(fieldNum))
    units = STRTRIM(description.units(fieldNum))
    comment = STRTRIM(description.comment(fieldNum))
;
    read_CCDA_data
;
    ne_img,dataArray,xSize=description.iSize,$
           ySize=description.jSize,title=title,$
           units=units,comment=comment
END



 PRO newsize
    common data, data_exists, description, dataArray, headerArray, titleArray, $
             unitsArray, commentArray, numFields, fieldNum

    title = STRTRIM(description.title(fieldNum))
    units = STRTRIM(description.units(fieldNum))
    comment = STRTRIM(description.comment(fieldNum))
;
    ne_img,dataArray,xSize=description.iSize,$
           ySize=description.jSize,title=title,$
           units=units,comment=comment
 END

;+
;* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
;
; ROUTINE:    ne_image
;
; AUTHOR:    Chuck Chaapel, STC-METSAT, 3/22/96
;            dave randel to make no-edit (ne) version with different size
;               input fields supported
;
; USAGE:    ne_image,data,iSize,jSize,title,units,comment
;
;* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
;-


;-------------------------------------------------------------------------------
;    EVENT HANDLER FOR new min max WIDGET
;-------------------------------------------------------------------------------

PRO NEWMM_EVENT, event

common full_image_butts, full_smooth_button, full_map_button, full_next_button, $
       full_prev_button,full_cancel_button,full_window_active,full_mapcent_button,$
       full_newmm_button,full_size_button,full_box_button,full_glbave_button,full_label_button
COMMON NEWMMevent, eventmin, eventmax, minval, maxval
common data_stuff, datamn, datamx, immset, fdatamn, fdatamx

Widget_Control, event.id, GET_UVALUE = eventval

CASE eventval OF
     'eventmin'	: BEGIN
		    WIDGET_CONTROL, eventmin, GET_VALUE = cdatamn
                    datamn = float(cdatamn)
                    immset = 1
		  END
     'eventmax'	: BEGIN
		    WIDGET_CONTROL, eventmax, GET_VALUE = cdatamx
                    datamx = float(cdatamx)
                    immset = 1
		  END
     'datamm'   : BEGIN
                    datamn = fdatamn
                    datamx = fdatamx
                    immset = 0
                  END
     'DONE'	: BEGIN
		  WIDGET_CONTROL, event.top, /DESTROY
                  draw_full_roi=1
                  full_window_active=1
                  WIDGET_CONTROL, full_map_button,     sensitive=1
                  WIDGET_CONTROL, full_cancel_button,  sensitive=1
                  WIDGET_CONTROL, full_smooth_button,  sensitive=1
                  WIDGET_CONTROL, full_next_button,    sensitive=1
                  WIDGET_CONTROL, full_prev_button,    sensitive=1
                  WIDGET_CONTROL, full_newmm_button,   sensitive=1
                  WIDGET_CONTROL, full_size_button,    sensitive=1
                  WIDGET_CONTROL, full_box_button,     sensitive=1
                  WIDGET_CONTROL, full_glbave_button,  sensitive=1
                  WIDGET_CONTROL, full_label_button,   sensitive=1
                  WIDGET_CONTROL, full_mapcent_button, sensitive=1

		  END
ENDCASE
END

;-------------------------------------------------------------------------------
;    EVENT HANDLER FOR ZOOM_IMAGE WIDGETS
;-------------------------------------------------------------------------------
pro ZOOM_IMG_EVENT, ev

common full_draw_vars, full_window, draw_full_roi, old_box, new_box
common full_img_vars, work_data, byteimage, full_2x_image, full_width, full_height, $
       full_x_dist, full_y_dist
common full_image_butts, full_smooth_button, full_map_button, full_next_button, $
       full_prev_button,full_cancel_button,full_window_active,full_mapcent_button,$
       full_newmm_button,full_size_button,full_box_button,full_glbave_button,full_label_button
common zoom_img_vars, zoom_data, zoom_data_box, zoom_image, zoom_start_x, zoom_end_x, $
       zoom_start_y, zoom_end_y,botlat,beglon,latinc,loninc
common map_vars, draw_map, smooth_map, center_map, labelon
common display_scale, data_max, data_type
common temp_vars, new_data
common pix_vars, changed_pix, temp_changed_pix, changed_time, temp_changed_time, new_pix
common time_vars, current_time

    WIDGET_CONTROL, ev.id, GET_UVALUE = eventval

    CASE eventval OF


;-----  CANCEL  -----

        'ZOOM_CANCEL':begin
            draw_full_roi=1
            full_window_active=1
            WIDGET_CONTROL, full_map_button,     sensitive=1
            WIDGET_CONTROL, full_cancel_button,  sensitive=1
            WIDGET_CONTROL, full_smooth_button,  sensitive=1
            WIDGET_CONTROL, full_next_button,    sensitive=1
            WIDGET_CONTROL, full_prev_button,    sensitive=1
            WIDGET_CONTROL, full_newmm_button,   sensitive=1
            WIDGET_CONTROL, full_size_button,    sensitive=1
            WIDGET_CONTROL, full_box_button,     sensitive=1
            WIDGET_CONTROL, full_glbave_button,  sensitive=1
            WIDGET_CONTROL, full_label_button,  sensitive=1
            WIDGET_CONTROL, full_mapcent_button, sensitive=1
            WIDGET_CONTROL, ev.top, /DESTROY
        end

        'ZOOM_SMOOTH': begin
            if(smooth_map eq 1) then begin
               smooth_map = 0
;               zoom_image=temporary(rebin(byteimage(zoom_start_x:zoom_end_x,zoom_start_y:zoom_end_y),$
               zoom_image=rebin(byteimage(zoom_start_x:zoom_end_x,zoom_start_y:zoom_end_y),$
               (zoom_end_x-zoom_start_x+1)*35,(zoom_end_y-zoom_start_y+1)*35)
            endif else begin
               smooth_map = 1
;               zoom_image=temporary(rebin(byteimage(zoom_start_x:zoom_end_x,zoom_start_y:zoom_end_y),$
               zoom_image=rebin(byteimage(zoom_start_x:zoom_end_x,zoom_start_y:zoom_end_y),$
               (zoom_end_x-zoom_start_x+1)*35,(zoom_end_y-zoom_start_y+1)*35,/sample)
            endelse
            TV,zoom_image,/order
;            if(draw_map eq 1) then begin
                 zoommap,botlat,beglon,latinc,loninc
;            endif
        end


;-----  DEFAULT  -----

        else:begin
        end
    ENDCASE
end

;-------------------------------------------------------------------------------
;    EVENT HANDLER FOR FULL_IMAGE WIDGETS
;-------------------------------------------------------------------------------
pro FULL_IMG_EVENT, ev

common full_draw_vars, full_window, draw_full_roi, old_box, new_box
common full_nav_vars, full_lat_value, full_lon_value, full_data_value, $
       full_min_value,full_max_value,full_glb_value
common full_img_vars, work_data, byteimage, full_2x_image, full_width, $
       full_height, full_x_dist, full_y_dist
common full_image_butts, full_smooth_button, full_map_button, full_next_button, $
       full_prev_button,full_cancel_button,full_window_active,full_mapcent_button,$
       full_newmm_button,full_size_button,full_box_button,full_glbave_button,full_label_button
common zoom_img_vars, zoom_data, zoom_data_box, zoom_image, zoom_start_x, $
       zoom_end_x, zoom_start_y, zoom_end_y,botlat,beglon,latinc,loninc
common data, data_exists, description, dataArray, headerArray, titleArray, $
       unitsArray, commentArray, numFields, fieldNum
common map_vars, draw_map, smooth_map, center_map, labelon
common display_scale, data_max, data_type
common pix_vars, changed_pix, temp_changed_pix, changed_time, temp_changed_time, new_pix
common zoom_stuff, izx,izy,izfac, mapclr, mapcent, imgsize, imgdispnum
common data_stuff, datamn, datamx, immset, fdatamn, fdatamx
COMMON NEWMMevent, eventmin, eventmax, minval, maxval
common glb, globalave,glbdisp,glbave_string,databox

    datamn1 = fltarr(1)
    datamx1 = fltarr(1)
    globalave=fltarr(3)

    WIDGET_CONTROL, ev.id, GET_UVALUE = eventval

    latinc = 180. / izy
    loninc = 360. / izx

    startlat = 90. - (.5*latinc)

    CASE eventval OF



;-----  FULL IMAGE WINDOW  -----

        'DRAW_FULL_WIN_EVENT': begin
            min_str=STRING(datamn,format='(F7.2)')
            max_str=STRING(datamx,format='(F7.2)')
            if(full_window_active eq 1) then begin

	    WSET, FULL_WINDOW

; calculate box parameters depending on cursor position
                startlon = 0.0
                i=fix(ev.x/izfac)
                j=fix((((izfac*full_height)-1)-ev.y)/izfac)

                box_center_x=fix(ev.x/izfac)*izfac
                box_center_y=fix(ev.y/izfac)*izfac


                box_left_x=box_center_x-(izfac*full_x_dist)
                if(box_left_x lt 0) then box_left_x=0
                box_right_x=box_left_x+((2*(izfac*full_x_dist))+0)   ;+3
                if(box_right_x gt (izfac*full_width)-1) then begin
                    box_right_x=(izfac*full_width)-1
                    box_left_x=box_right_x-((2*(izfac*full_x_dist))+0)
                endif

                box_bott_y=box_center_y-(izfac*full_y_dist)
                if(box_bott_y lt 0) then box_bott_y=0
                box_top_y=box_bott_y+((2*(izfac*full_y_dist))+0)    ;+3
                if(box_top_y gt (izfac*full_height)-1) then begin
                    box_top_y=(izfac*full_height)-1
                    box_bott_y=box_top_y-((2*(izfac*full_y_dist))+0)
                endif

; continuous update of full window cursor with NO BUTTON PRESSES

                if (ev.press EQ 0) and (ev.release EQ 0) then begin

                    if(draw_full_roi eq 1) then begin
                        device, get_graphics = old_graphics, set_graphics = 6  ;Set xor
                        box_color = 232

                        old_box=new_box
                        new_box(0,0)=box_left_x
                        new_box(0,1)=box_right_x
                        new_box(0,2)=box_right_x
                        new_box(0,3)=box_left_x
                        new_box(0,4)=box_left_x
                        new_box(1,0)=box_top_y
                        new_box(1,1)=box_top_y
                        new_box(1,2)=box_bott_y
                        new_box(1,3)=box_bott_y
                        new_box(1,4)=box_top_y

                        plots,old_box(0,*),old_box(1,*),color=box_color,/device,thick=1
                        plots,new_box(0,*),new_box(1,*),color=box_color,/device,thick=1
                        device, set_graphics = old_graphics
                    endif

                    if(mapcent eq 0) then startlon = -180
                    lon= startlon + float(i*loninc)+(0.5*loninc)
                    lat=90.-float(j*latinc)-(0.5*latinc)

                    lat_str=STRING(lat,format='(F7.2)')
                    lon_str=STRING(lon,format='(F7.2)')
                    data_string=temporary(STRING(work_data(i,j),format='(F8.2)'))

                    WIDGET_CONTROL, full_lat_value, $
                        SET_VALUE=lat_str
                    WIDGET_CONTROL, full_lon_value, $
                        SET_VALUE=lon_str
                    WIDGET_CONTROL, full_data_value, $
                        SET_VALUE=data_string
                    WIDGET_CONTROL, full_min_value, $
                        SET_VALUE=min_str
                    WIDGET_CONTROL, full_max_value, $
                        SET_VALUE=max_str
                    if(glbdisp eq 1) then begin
                         WIDGET_CONTROL, full_glb_value, SET_VALUE=glbave_string
                    endif



; zoom a section of small window with a BUTTON PRESS inside window

                endif else if (ev.press EQ 1) and (ev.release EQ 0) then begin
                    if(mapcent eq 0) then startlon = -180
                    tlon= startlon + float(i*loninc)+(0.5*loninc)
                    tlat=90.-float(j*latinc)-(0.5*latinc)
                    toplat = tlat + (7*latinc) + (latinc/2.)
                    botlat = tlat - (7*latinc) - (latinc/2.)
                    beglon = tlon - (7*loninc) - (loninc/2.)
                    endlon = tlon + (7*loninc) + (loninc/2.)

                    if(toplat gt 90.)  then botlat = 90. - (15.0*latinc)
                    if(botlat lt -90.) then botlat = -90.

                    if(startlon eq -180) then begin
                        if(beglon lt -180.) then beglon = -180.
                        if(endlon gt 180.)  then beglon = 180. - (15.0*loninc)
                    endif else begin
                        if(beglon lt 0.0)  then beglon = 0.0
                        if(endlon gt 360.) then beglon = 360. - (15.0*loninc)
                    endelse

                    draw_full_roi=0
                    zoom_start_x=i-full_x_dist
                    if(zoom_start_x lt 0) then zoom_start_x=0
                    zoom_end_x=zoom_start_x+14
                    if(zoom_end_x gt izx-1) then begin
                        zoom_end_x=izx-1
                        zoom_start_x=zoom_end_x-14
                    endif
                    zoom_start_y=j-full_y_dist
                    if(zoom_start_y lt 0) then zoom_start_y=0
                    zoom_end_y=zoom_start_y+14
                    if(zoom_end_y gt izy-1) then begin
                        zoom_end_y=izy-1
                        zoom_start_y=zoom_end_y-14
                    endif

                    zoom_data=work_data(zoom_start_x:zoom_end_x,zoom_start_y:zoom_end_y)

                    zoom_main_base = WIDGET_BASE(title='Display Individual '+description.title(fieldNum)$
                                                  +' Elements',/COLUMN,xpad=0)
                    zoom_window_base = WIDGET_BASE(zoom_main_base,/ROW,xpad=0,space=0)

                    zoom_image_window = widget_draw(zoom_window_base,xsize=480,ysize=475, $
                        /frame,/button_events)               ;385

                    zoom_data_base=intarr(15)
                    for col=0,14 do begin
                        zoom_data_base(col)=WIDGET_BASE(zoom_window_base,/COLUMN,xpad=0,space=7)   ;10,2
                    endfor

                    zoom_button_base = WIDGET_BASE(zoom_main_base,/ROW,xpad=0,space=0)

                    zoom_data_box=intarr(15,15)
                    for row=0,14 do begin
                        for col=0,14 do begin
                            data_string=temporary(STRING(zoom_data(col,row),format='(F5.1)'))
                            if(data_string eq '999.9') then begin
                                 data_string = '     '
                            endif
                            zoom_data_box(col,row)=WIDGET_TEXT(zoom_data_base(col),font='4x7',$
                                                   xsize=4,ysize=1,value=data_string)
                        endfor
                    endfor

                    zoom_cancel_button = WIDGET_BUTTON(zoom_button_base, value='   Return   ',$
                                         uvalue='ZOOM_CANCEL',frame=3)
                    zoom_smooth_button = WIDGET_BUTTON(zoom_button_base, value=' Smooth/Crude ',$
                                         uvalue='ZOOM_SMOOTH',frame=3)
                    WIDGET_CONTROL, /REAL, zoom_main_base
                    WIDGET_CONTROL, zoom_image_window, get_value=ZOOM_WINDOW
                    WSET, ZOOM_WINDOW

                    if(smooth_map eq 1) then begin
;                         zoom_image=temporary(rebin(byteimage(zoom_start_x:zoom_end_x,zoom_start_y:zoom_end_y),$
                         zoom_image=rebin(byteimage(zoom_start_x:zoom_end_x,zoom_start_y:zoom_end_y),$
                        (zoom_end_x-zoom_start_x+1)*32,(zoom_end_y-zoom_start_y+1)*32,/sample)   ;35
                    endif else begin
;                         zoom_image=temporary(rebin(byteimage(zoom_start_x:zoom_end_x,zoom_start_y:zoom_end_y),$
                         zoom_image=rebin(byteimage(zoom_start_x:zoom_end_x,zoom_start_y:zoom_end_y),$
                        (zoom_end_x-zoom_start_x+1)*32,(zoom_end_y-zoom_start_y+1)*32)           ;35
                    endelse

                    TV,zoom_image,/order
;                    if(draw_map eq 1) then begin
                        zoommap,botlat,beglon,latinc,loninc
;                    endif
                    full_window_active=0
                     XMANAGER, 'ZOOM_IMG', zoom_main_base, event='ZOOM_IMG_EVENT', $
                        GROUP_LEADER = zoom_main_base
                endif
            endif
        end

;-----  SMOOTH IMAGE ---------

         'FULL_SMOOTH': begin
            if(smooth_map eq 1) then begin
;                 full_2x_image=temporary(rebin(byteimage,izx*izfac,izy*izfac))
                 full_2x_image=rebin(byteimage,izx*izfac,izy*izfac)
                 smooth_map=0
            endif else begin
                 full_2x_image=rebin(byteimage,izx*izfac,izy*izfac,/sample)
;                 full_2x_image=temporary(rebin(byteimage,izx*izfac,izy*izfac,/sample))
                 smooth_map=1
            endelse
            WSET, FULL_WINDOW
            TV, full_2x_image,/order
            new_box(*,*)=0
            if(draw_map eq 1) then begin
                 dispmap
            endif
            if(labelon eq 1) then labelstring
          end

;-----  MAP TOGGLE  -----

        'FULL_MAP':begin
            if(draw_map eq 1) then begin
                if(mapclr eq 235) then begin
                    mapclr = 234
                    dispmap
                endif else begin
                    WSET, FULL_WINDOW
                    TV, full_2x_image,/order
                    new_box(*,*)=0
                    draw_map=0
                    mapclr = 235
                endelse
            endif else begin
                WSET, FULL_WINDOW
                dispmap
                draw_map=1
            endelse
            if(labelon eq 1) then labelstring
        end

;------ MAP CENTER -----

        'FULL_MAPCENT':begin
            if(center_map eq 0) then begin
                 mapcent = 180
                 center_map = 180
            endif else begin
                 mapcent = 0
                 center_map = 0
            endelse

            WSET, FULL_WINDOW
            byteimage = shift(byteimage,izx/2,0)
            work_data = shift(work_data,izx/2,0)

            if(smooth_map eq 1) then full_2x_image=rebin(byteimage,izx*izfac,izy*izfac,/sample)
            if(smooth_map eq 0) then full_2x_image=rebin(byteimage,izx*izfac,izy*izfac)

            TV, full_2x_image,/order
            new_box(*,*)=0
            if(draw_map eq 1) then begin
                dispmap
            endif
            if(labelon eq 1) then labelstring
        end

;----- NEXT IMAGE ------

        'FULL_NEXT':begin
            WIDGET_CONTROL, ev.top, /DESTROY
            nxpre = 1
            nextprev, nxpre
         end


;----- PREV IMAGE ------

        'FULL_PREV':begin
            WIDGET_CONTROL, ev.top, /DESTROY
            nxpre = -1
            nextprev, nxpre
        end


;----- NEW MAX/MIN IMAGE ------

        'FULL_NEWMM':begin
            full_window_active = 0
            WIDGET_CONTROL, full_smooth_button,  sensitive=0
            WIDGET_CONTROL, full_map_button,     sensitive=0
            WIDGET_CONTROL, full_cancel_button,  sensitive=0
            WIDGET_CONTROL, full_glbave_button,  sensitive=0
            WIDGET_CONTROL, full_label_button,   sensitive=0
            WIDGET_CONTROL, full_next_button,    sensitive=0
            WIDGET_CONTROL, full_prev_button,    sensitive=0
            WIDGET_CONTROL, full_newmm_button,   sensitive=0
            WIDGET_CONTROL, full_size_button,    sensitive=0
            WIDGET_CONTROL, full_box_button,     sensitive=0
            WIDGET_CONTROL, full_mapcent_button, sensitive=0

            c1datamn = string(datamn)
            c1datamx = string(datamx)
            newmmbase = Widget_Base(Title='Enter New Min/Max', /COLUMN,xoffset=450,yoffset=225)
            box1 = WIDGET_BASE(newmmbase, /COLUMN, /FRAME)
            minlabel = WIDGET_LABEL(box1, Value = 'Minimum : ')
            eventmin = WIDGET_TEXT(box1, /Frame, /EDITABLE, UValue = 'eventmin')
            WIDGET_CONTROL, eventmin, SET_VALUE = c1datamn
            maxlabel = WIDGET_LABEL(box1, Value = 'Maximum : ')
            eventmax = WIDGET_TEXT(box1, /Frame, /EDITABLE, UValue = 'eventmax')
            WIDGET_CONTROL, eventmax, SET_VALUE = c1datamx
            setmm_butt = WIDGET_BUTTON(newmmbase, UVALUE = 'datamm', VALUE = '  Use DATA Min/Max  ')
            done_butt  = WIDGET_BUTTON(newmmbase, UVALUE = 'DONE', VALUE ='     Re-Display     ')
            Widget_Control, newmmbase, /REALIZE, /HOURGLASS
            XManager, 'NEWMM', newmmbase, event='NEWMM_EVENT',/modal

;now that we've got the new values, REDISPLAY the plot with a new or data min and max

            datamn1(0) = datamn
            datamx1(0) = datamx + 0.001
            newtop = 233
            byteimage=bytscl(work_data,min=datamn1(0),max=datamx1(0),top=newtop)
            byteimage=(work_data EQ 999.9)*234 + (work_data LT 999.9)*byteimage
            if(smooth_map eq 1) then begin
;                 full_2x_image=temporary(rebin(byteimage,izx*izfac,izy*izfac,/sample))
                 full_2x_image=rebin(byteimage,izx*izfac,izy*izfac,/sample)
            endif else begin
;                 full_2x_image=temporary(rebin(byteimage,izx*izfac,izy*izfac))
                 full_2x_image=rebin(byteimage,izx*izfac,izy*izfac)
            endelse
            WSET, FULL_WINDOW
            print,' redisplaying with new min/max'
            TV, full_2x_image,/order
            new_box(*,*)=0
            if(draw_map eq 1) then begin
                 dispmap
            endif
            if(labelon eq 1) then labelstring
        END

;----- CALC AND DISPLAY GLOBAL AVES

        'FULL_GLBAVE':begin
            glbdisp = 1
            dellat = -latinc
            print,'Calculating Global Averages'
            ccdaglb,work_data,startlat,dellat,loninc,izx,izy,globalave
            strnh = string(globalave(0),format='(F7.2)')
            strsh = string(globalave(1),format='(F7.2)')
            strglb = string(globalave(2),format='(F7.2)')
            glbave_string = ['  ',strglb,'  ',strnh,'  ',strsh]
            dispclrbar
            xpalette, GROUP = ev.top
         END

;----- DISPLAY THE DATA BOX, TAKE OFF TO CAPTURE SCREEN

        'FULL_BOX':begin
            if(draw_full_roi eq 1) then begin
                 draw_full_roi = 0
                 TV, full_2x_image,/order
                 new_box(*,*) = 0
                 if(draw_map eq 1) then begin
                      dispmap
                 endif
                 if(labelon eq 1) then labelstring
            endif else begin
                 draw_full_roi = 1
            endelse
         END

;-----  CHANGE SIZE -----

        'FULL_SIZE':begin
            if(imgsize eq 1440) then begin
                 imgsize = 720
            endif else if(imgsize eq 720) then begin
                 imgsize = 1440
            endif
            WIDGET_CONTROL, ev.top, /DESTROY
            newsize
            if(labelon eq 1) then labelstring
         END


;-----  ADD LABEL -----

        'FULL_LABEL':begin
	    if(labelon eq 0) then begin
		    labelstring
	        labelon = 1
            endif else begin
                TV, full_2x_image,/order
                labelon = 0
                if(draw_map eq 1) then begin
                    dispmap
                endif
            endelse
         END


;-----  CANCEL  -----

        'FULL_CANCEL':begin
            temp_changed_pix=0
            temp_changed_time=""
            WIDGET_CONTROL, ev.top, /DESTROY
        end

;-----  DEFAULT  -----

        else:begin
        end
    ENDCASE
end

;-------------------------------------------------------------------------------
;    SETUP FOR DISPLAY OF FULL, zoomed SCALED IMAGE
;-------------------------------------------------------------------------------
pro ne_img, orig_data, xSize=xSize, ySize=ySize, title=title, units=units,comment=comment, TOP_ID=BASE, GROUP = GROUP

common full_draw_vars, full_window, draw_full_roi, old_box, new_box
common full_nav_vars, full_lat_value, full_lon_value, full_data_value, $
       full_min_value,full_max_value,full_glb_value
common full_img_vars, work_data, byteimage, full_2x_image, full_width, $
       full_height, full_x_dist, full_y_dist
common full_image_butts, full_smooth_button, full_map_button, full_next_button, $
       full_prev_button,full_cancel_button,full_window_active,full_mapcent_button,$
       full_newmm_button,full_size_button,full_box_button,full_glbave_button,full_label_button
common map_vars, draw_map, smooth_map, center_map, labelon
common display_scale, data_max, data_type
common time_vars, current_time
common data_stuff, datamn, datamx, immset, fdatamn, fdatamx
common zoom_stuff, izx, izy, izfac, mapclr, mapcent, imgsize, imgdispnum
common glb, globalave,glbdisp,glbave_string,databox

    current_time=strmid(strcompress(units),0,11)
    full_width=xSize
    full_height=ySize
    full_x_dist=7
    full_y_dist=7
    cdatamn = ' '
    cdatamx = ' '
    datamn2 = fltarr(1)
    datamx2 = fltarr(1)
    glbdisp = 0
    databox = 0
    glbave_string = ' '

    full_main_base = WIDGET_BASE(title=title+'          '+units,/COLUMN,xpad=5,ypad=0,space=0)
    full_top_base = WIDGET_BASE(full_main_base,/ROW,xpad=5,ypad=5,space=10)

    full_lat_base = widget_base(full_top_base,/COLUMN)
    full_lat_label = widget_label(full_lat_base,value='Lat')
    full_lat_value = widget_text(full_lat_base,xsize=7)
    WIDGET_CONTROL, full_lat_value,sensitive=0

    full_lon_base = widget_base(full_top_base,/COLUMN)
    full_lon_label = widget_label(full_lon_base,value='Lon')
    full_lon_value = widget_text(full_lon_base,xsize=7)
    WIDGET_CONTROL, full_lon_value,sensitive=0

    full_data_base = widget_base(full_top_base,/COLUMN)
    full_data_label = widget_label(full_data_base,value=' Data Value ')
    full_data_value = widget_text(full_data_base,xsize=7)
    WIDGET_CONTROL, full_data_value,sensitive=0

    full_min_base = widget_base(full_top_base,/COLUMN)
    full_min_label = widget_label(full_min_base,value='Minimum')
    full_min_value = widget_text(full_min_base,/editable,xsize=7)
    WIDGET_CONTROL, full_min_value,sensitive=0

    full_max_base = widget_base(full_top_base,/COLUMN)
    full_max_label = widget_label(full_max_base,value='Maximum')
    full_max_value = widget_text(full_max_base,/editable,xsize=7)
    WIDGET_CONTROL, full_max_value,sensitive=0

    full_glb_base = widget_base(full_top_base,/COLUMN)
    full_glb_label = widget_label(full_glb_base,value='GLB       NH        SH')
    full_glb_value = widget_text(full_glb_base,/editable,xsize=25)
    WIDGET_CONTROL, full_glb_value,sensitive=0


    full_middle_base = WIDGET_BASE(full_main_base, /ROW,xpad=0,ypad=0,space=0)

    izfac = LONG( imgsize / Xsize)
    izx = Xsize
    izy = YSize

    full_image_window = widget_draw(full_middle_base,xsize=xSize*izfac,ysize=ysize*izfac, $
        /frame,/motion_events,/button_events, uvalue='DRAW_FULL_WIN_EVENT')

    if(imgsize eq 720) then begin
         full_bottom_base   = widget_base(full_main_base, ROW=2,xpad=10,ypad=5,space=10)
    endif else begin
         full_bottom_base   = widget_base(full_main_base, ROW=1,xpad=10,ypad=5,space=10)
    endelse
    full_map_button    = WIDGET_BUTTON(full_bottom_base, value=' Map', uvalue='FULL_MAP',frame=3)
    full_mapcent_button= WIDGET_BUTTON(full_bottom_base, value=' Map Center ', uvalue='FULL_MAPCENT',frame=3)
    full_label_button  = WIDGET_BUTTON(full_bottom_base, value=' Date Label ', uvalue='FULL_LABEL', frame=3)
    full_smooth_button = WIDGET_BUTTON(full_bottom_base, value=' Smooth/Crude ',uvalue='FULL_SMOOTH',frame=3)
    full_newmm_button  = WIDGET_BUTTON(full_bottom_base, value=' New Min/Max ',uvalue='FULL_NEWMM',frame=3)
    full_size_button   = WIDGET_BUTTON(full_bottom_base, value=' Change Size ',uvalue='FULL_SIZE',frame=3)
    full_box_button    = WIDGET_BUTTON(full_bottom_base, value=' Show Zoom Box ',uvalue='FULL_BOX',frame=3)
    full_glbave_button = WIDGET_BUTTON(full_bottom_base, value=' Global Ave / Color ',uvalue='FULL_GLBAVE',frame=3)
    full_prev_button   = WIDGET_BUTTON(full_bottom_base, value=' Previous Field',uvalue='FULL_PREV',frame=3)
    full_next_button   = WIDGET_BUTTON(full_bottom_base, value=' Next Field ',uvalue='FULL_NEXT',frame=3)
    full_cancel_button = WIDGET_BUTTON(full_bottom_base, value=' Return ',uvalue='FULL_CANCEL',frame=3)

    WIDGET_CONTROL, /REAL, full_main_base
    WIDGET_CONTROL, full_image_window,sensitive=0
    WIDGET_CONTROL, /hourglass
    WIDGET_CONTROL, full_image_window, get_value=FULL_WINDOW


; find min max of data without using missing value (999.9)
    if(immset eq 0) then begin
         datamn = min(orig_data)
         datamx = max(orig_data)
         if(datamx eq 999.9) then begin
              orig_data(WHERE(orig_data eq 999.9)) = datamn - 1.0
              datamx = max(orig_data)
              orig_data(WHERE(orig_data eq datamn-1.0)) = 999.9
         endif
         fdatamn = datamn
         fdatamx = datamx
    endif else begin
         fdatamn = min(orig_data)
         fdatamx = max(orig_data)
         if(fdatamx eq 999.9) then begin
              orig_data(WHERE(orig_data eq 999.9)) = fdatamn - 1.0
              fdatamx = max(orig_data)
              orig_data(WHERE(orig_data eq fdatamn-1.0)) = 999.9
         endif
    endelse

; get the original image data & create expanded image

    if(imgdispnum eq 0) then begin
         work_data = orig_data
         imgdispnum = 1
    endif


    datamn2(0) = datamn
    datamx2(0) = datamx + 0.001
    newtop = 233
    byteimage=bytscl(work_data,min=datamn2(0),max=datamx2(0),top=newtop)
    byteimage=(work_data EQ 999.9)*234 + (work_data LT 999.9)*byteimage
    if(mapcent ne center_map) then begin
         byteimage = shift(byteimage,izx/2,0)
         work_data = shift(work_data,izx/2,0)
         mapcent = center_map
    endif
;    if(smooth_map eq 1) then full_2x_image=temporary(rebin(byteimage,izx*izfac,izy*izfac,/sample))
;    if(smooth_map eq 0) then full_2x_image=temporary(rebin(byteimage,izx*izfac,izy*izfac))

    if(smooth_map eq 1) then full_2x_image=rebin(byteimage,izx*izfac,izy*izfac,/sample)
    if(smooth_map eq 0) then full_2x_image=rebin(byteimage,izx*izfac,izy*izfac)

; show the 2X image

    WIDGET_CONTROL, full_image_window,sensitive=1
    WSET, FULL_WINDOW
    TV, full_2x_image,/order

    draw_full_roi=1
    full_window_active=1

; put on the map

    if(draw_map eq 1) then dispmap
    if(labelon eq 1) then labelstring

    old_box=intarr(2,5)
    old_box(*,*)=0
    new_box=intarr(2,5)
    new_box(*,*)=0

; let xmanager handle the window

    XMANAGER, 'FULL_IMAGE', full_main_base, event='FULL_IMG_EVENT', $
        GROUP_LEADER = full_main_base

end
;+
;* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
;
; ROUTINE:   disp
;
; AUTHOR:    Chuck Chaapel, STC-METSAT, 3/20/96
;
; USAGE:    disp
;
; PURPOSE:    display CCDA formatted NVAP data files & allow data manipulation
;
; INPUT:    none
;
; OUTPUT:    display
;
; LIMITATIONS:
;
;* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
;-

;-------------------------------------------------------------------------------
;    EVENT HANDLER FOR QC WIDGETS
;-------------------------------------------------------------------------------
pro qc_event,event

common input_file_vars, curr_in_path, curr_in_filter, curr_in_file
common output_file_vars, curr_out_path, curr_out_filter, curr_out_file, curr_out_pts
common pix_file_vars, curr_pix_path, curr_pix_file
common data, data_exists, description, dataArray, headerArray, titleArray, unitsArray, $
             commentArray, numFields, fieldNum
common display_scale, data_max, data_type
common main_message, message_box
common pix_vars, changed_pix, temp_changed_pix, changed_time, temp_changed_time, new_pix

; get the event that occured

    widget_control,event.id,get_uvalue=eventval

; do the selected procedure

    case eventval of

; quit

        "QUIT":begin
            widget_control,event.top,/destroy
        end

; read CCDA formatted file

        "OPEN":begin

; widgetized file picker

            if (curr_in_path eq "") then begin
                curr_in_file = "*.nat"
                input=pickfile(title='Read CCDA Data File',file=curr_in_file,get_path=curr_in_path,filter=curr_in_filter,/must_exist,/noconfirm)
            endif else begin
                curr_in_file = "*.nat"
                input=pickfile(title='Read CCDA Data File',path=curr_in_path,file=curr_in_file,get_path=curr_in_path,filter=curr_in_filter,/must_exist,/noconfirm)
            endelse
            if (strlen(input)eq 0) then return

; attempt to open the file
;my fix           input = input+' '
            openr,unit,/get_lun,error=return_code,input

; handle an error on file open

            if (return_code ne 0) then begin
                print,'Error opening file '+input
            endif else begin
                free_lun,unit
                curr_in_file=input
                FILEBRK, curr_in_file, EXTENSION=data_type

; set some data display variables depending on data type
;   data_max = maximum value for use in display scaling by bytscl
;
;my fix               curr_in_filter="*."+data_type
                curr_in_filter="*.nat"

; reset arrays holding changed points

                changed_pix=0
                changed_time=""
                temp_changed_pix=0
                temp_changed_time=""

; make pixel file name
                filebrk,curr_in_file,name=filename
                curr_pix_file=curr_pix_path+filename+".pix"

; call readCCDA to read the data format & display field listing

                rdCCDAdi, curr_in_file, curr_pix_file
            endelse
        end
    endcase
end

;-------------------------------------------------------------------------------
;    SETUP AND INITIALIZATION FOR QC WIDGETS
;-------------------------------------------------------------------------------
;pro nvap_display
pro nvap_all_idl

common input_file_vars, curr_in_path, curr_in_filter, curr_in_file
common output_file_vars, curr_out_path, curr_out_filter, curr_out_file
common pix_file_vars, curr_pix_path, curr_pix_file
common main_butts, select_button, save_button, quit_button
common main_message, message_box
common map_vars, draw_map, smooth_map, center_map, labelon
common data, data_exists, description, dataArray, headerArray, titleArray, unitsArray, $
       commentArray, numFields, fieldNum
common pix_vars, changed_pix, temp_changed_pix, changed_time, temp_changed_time, new_pix
common zoom_stuff, izx, izy, izfac, mapclr, mapcent, imgsize, imgdispnum

; initialize file paths

    curr_in_path=""
    curr_in_filter="*.nat"
    curr_in_file="*.nat"
    curr_out_path=" "
    curr_out_filter="*.nat"
    curr_out_file=""
    curr_pix_path=" "
    curr_pix_file=""
    mapclr = 235
    smooth_map = 1
    center_map = 180
    draw_map=1
	labelon = 0
    data_exists=0
    new_pix=fltarr(1,4)
    changed_pix=0
    changed_time=""
    temp_changed_pix=0
    temp_changed_time=""
    nmapread = 0

; define color table
    device,decompose=0
    WINDOW, /PIXMAP, /FREE
    Def_Clrs
    WDELETE, !D.WINDOW

; define the main button window

    base=widget_base(/column,xpad=10,ypad=10,space=0,title='CCDA 720x360 Format Field Display')
    button_base=widget_base(base,/row)
    select_button = WIDGET_BUTTON(button_base, value=' O P E N  F I L E ',uvalue='OPEN',frame=3)
    quit_button = WIDGET_BUTTON(button_base, value='   Q U I T   ',uvalue='QUIT',frame=3)
    message_box = WIDGET_TEXT(base, value='')
    widget_control,base,/realize,/map
    widget_control,select_button,/input_focus

    xmanager,'qc',base
end